Gecko [ nrupathungauniversityblr.ac.in ]

Name	Size	Permission
internal	[ DIR ]	drwxr-xr-x
amversion.m4	1.58 KB	-rw-r--r--
ar-lib.m4	2.02 KB	-rw-r--r--
as.m4	767 B	-rw-r--r--
auxdir.m4	2.35 KB	-rw-r--r--
cond-if.m4	1.01 KB	-rw-r--r--
cond.m4	1.01 KB	-rw-r--r--
depend.m4	7.11 KB	-rw-r--r--
depout.m4	2.93 KB	-rw-r--r--
dmalloc.m4	906 B	-rw-r--r--
extra-recurs.m4	738 B	-rw-r--r--
gcj.m4	649 B	-rw-r--r--
init.m4	7.84 KB	-rw-r--r--
install-sh.m4	681 B	-rw-r--r--
lead-dot.m4	641 B	-rw-r--r--
lex.m4	689 B	-rw-r--r--
lispdir.m4	2.1 KB	-rw-r--r--
maintainer.m4	1.62 KB	-rw-r--r--
make.m4	1.3 KB	-rw-r--r--
missing.m4	1.13 KB	-rw-r--r--
mkdirp.m4	1.32 KB	-rw-r--r--
obsolete.m4	1008 B	-rw-r--r--
options.m4	1.06 KB	-rw-r--r--
prog-cc-c-o.m4	1.65 KB	-rw-r--r--
python.m4	8.98 KB	-rw-r--r--
runlog.m4	718 B	-rw-r--r--
sanity.m4	2.58 KB	-rw-r--r--
silent.m4	1.87 KB	-rw-r--r--
strip.m4	1.36 KB	-rw-r--r--
substnot.m4	675 B	-rw-r--r--
tar.m4	4.37 KB	-rw-r--r--
upc.m4	836 B	-rw-r--r--
vala.m4	1.62 KB	-rw-r--r--

Code Editor : prog-cc-c-o.m4

##                                                          -*- Autoconf -*-
# Copyright (C) 1999-2017 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# _AM_PROG_CC_C_O
# ---------------
# Like AC_PROG_CC_C_O, but changed for automake.  We rewrite AC_PROG_CC
# to automatically call this.
AC_DEFUN([_AM_PROG_CC_C_O],
[AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
AC_REQUIRE_AUX_FILE([compile])dnl
AC_LANG_PUSH([C])dnl
AC_CACHE_CHECK(
  [whether $CC understands -c and -o together],
  [am_cv_prog_cc_c_o],
  [AC_LANG_CONFTEST([AC_LANG_PROGRAM([])])
  # Make sure it works both with $CC and with simple cc.
  # Following AC_PROG_CC_C_O, we do the test twice because some
  # compilers refuse to overwrite an existing .o file with -o,
  # though they will create one.
  am_cv_prog_cc_c_o=yes
  for am_i in 1 2; do
    if AM_RUN_LOG([$CC -c conftest.$ac_ext -o conftest2.$ac_objext]) \
         && test -f conftest2.$ac_objext; then
      : OK
    else
      am_cv_prog_cc_c_o=no
      break
    fi
  done
  rm -f core conftest*
  unset am_i])
if test "$am_cv_prog_cc_c_o" != yes; then
   # Losing compiler, so override with the script.
   # FIXME: It is wrong to rewrite CC.
   # But if we don't then we get into trouble of one sort or another.
   # A longer-term fix would be to have automake use am__CC in this case,
   # and then we could set am__CC="\$(top_srcdir)/compile \$(CC)"
   CC="$am_aux_dir/compile $CC"
fi
AC_LANG_POP([C])])

# For backward compatibility.
AC_DEFUN_ONCE([AM_PROG_CC_C_O], [AC_REQUIRE([AC_PROG_CC])])

${this.title}

Code Editor : prog-cc-c-o.m4